Tweet from mIRC | mIRC Twitter

May 3, 2008 by Dave
 

Twitter is great, and it’s nice that there is more than one way to send a tweet (message) out, you can use Web, SMS or Google Talk (or even Digsby!). But what if you’re a heavy mIRC user, or if you just like to have more ways to tweet? Clint, on DALnet/#system was working on this, and I’ve added a few things that I think are worth sharing.

How can I use twitter through mIRC?

This would be entered into the Remote script section in mIRC:

alias tweet {
; use /tweet
set %tw.username twitter_username_here
set %tw.password twitter_password_here
; exit if the message is too long for twitter to take.
if ($len($1-) > 140) {
echo -a Sorry, that was $calc($len($1-)-140) characters too long!
halt
}
; connect to twitter on HTTP port 80
set %authentication $encode($+(%tw.username,:,%tw.password),m)
sockclose twitter
sockopen twitter twitter.com 80
; set a 2-second timeout in case there is a problem
; this could be changed to 5 or 10
.timertwitter 1 2 twitter_timeout
set %tweet $$1-
; store the text
}
 
; encoding is important for sending data to a web server
; the decode function is not used, but is here for the sake of
; completeness
alias urlencode return $regsubex($1-,/\G(.)/g,$iif(($prop && \1 !isalnum) || !$prop,$chr(37) $+ $base($asc(\1),10,16),\1))
alias urldecode return $replace($regsubex($1-,/%(\w\w)/g,$chr($iif($base(\t,16,10) != 32,$v1,1))),$chr(1),$chr(32))
 
; when the socket accepts our connection
on *:sockopen:twitter:{
sockwrite -n twitter POST /statuses/update.json HTTP/1.1
sockwrite -n twitter Host: twitter.com
sockwrite -n twitter User-Agent: Mozilla/5.0 (Windows; U; Windows NT 6.0; en-US; rv:1.9b5) Gecko/2008032620 Firefox/3.0b5
sockwrite -n twitter Content-Length: $calc($len($urlencode(%tweet)) + 9)
sockwrite -n twitter Authorization: Basic %authentication
sockwrite -n twitter $crlf
sockwrite twitter status=
sockwrite -n twitter $urlencode(%tweet)
sockwrite twitter $crlf
sockwrite twitter $crlf
; send the postdata
}
 
; the data wasn't returned, kill the socket
; and tell the user.
alias twitter_timeout {
echo -a Message Failed to Send - Socket Timeout
sockclose twitter
}
 
; we have data back
on *:sockread:twitter: {
.timertwitter off
sockread -f %string
echo -a Message Returned ( $+ %string $+ )
sockclose twitter
}

Hopefully this is useful to someone else, I often find myself updating twitter this way, because I always have mIRC open, albeit in the background.

Comments

3 Comments on Tweet from mIRC | mIRC Twitter

  1. Twitter desde un cliente mIRC | power.org.mx on Wed, 23rd Jul 2008 1:15 am

    2. [...] utilizarlos solo tecleamos /tweet mensaje referencia ↔ Dave Amenta – Tweet from mIRC | mIRC Twitter descarga ↓ Twitter – [...]

  2. Viper007Bond on Tue, 25th Aug 2009 7:05 am

    3. Just wanted to thank you for this. I was in need of some code to send a HTTP POST and this snippet helped a TON! :)

  3. Bouncy Castle Hire Weston-Super-Mare on Mon, 29th Mar 2010 11:38 am

    4. Great script but ownt work in my mirc :(

    Tahnks anyways

    the error i get is Message Failed to Send – Socket Timeout